Up ! Object Request Broker

Ceci est le fichier source du programme exécutable Up ! Object Request Broker.

Source Composant "Up ! Object Request Broker Server" Version 4.0.0; ImporterModule /************/


	UpsOrb(<UpsOrb.upi>, ImporterDefinitions);




Parametre >upsorb< Section "UpsOrb"

/*********************************/

Prive :

/*****/

   Action : Nul Ou Caractere;

   Detail : Booleen;

   Entete : Booleen;

   NomDeLAnnuaire "NomAnnuaire" : Nul Ou Caractere;

   Chemin : Nul Ou Caractere;

   SourceAnnuaire "Source": Nul Ou Caractere;



Prive :

/*****/

Fonction ExecuterCreerAnnuaire() Retourner Entier

/***********************************************/

Variable

/******/

   A : Nul Ou Annuaire;



Debut
Si NomDeLAnnuaire==Nul Alors

   Ecran.Ecrire(Message(UpsOrb,"UsageUpsSecCreerAnnuaire"));

   Retourner 1;

Fin Si



Si Detail Alors

   Ecran.Ecrire(Message(UpsOrb,"CreationDeLAnnuaire",NomDeLAnnuaire));


Fin Si

A=Annuaire(NomDeLAnnuaire);

A.MarquerModifie();

A.Enregistrer();

Ecran.Ecrire(Message(UpsOrb,"CreationAnnuaireTerminee", NomDeLAnnuaire));



Retourner 0;

Fin Fonction



Procedure EnvoyerMessage(MessageEnvoye : Caractere, ? : Entier, ? : Entier, ? : Nul Ou Caractere)

/***********************************************************************************************/

Debut

Ecran.Ecrire(MessageEnvoye);

Fin Procedure



Fonction ExecuterExporterAnnuaire() Retourner Entier

/**************************************************/

Variable

/******/

   A : Nul Ou Annuaire;



Debut

Si NomDeLAnnuaire==Nul Ou SourceAnnuaire==Nul Alors

   Ecran.Ecrire(Message(UpsOrb,"UsageUpsSecExporterAnnuaire"));

   Retourner 1;

Fin Si



Si Detail Alors

   Ecran.Ecrire(Message(UpsOrb,"ExportationDeLAnnuaire", SourceAnnuaire));

   A=Annuaire(NomDeLAnnuaire);

   Si A.Exporter(SourceAnnuaire, Chemin, EnvoyerMessage) Alors
   
      Ecran.Ecrire(Message(UpsOrb, "ExportationAnnuaireTermineeAvecSucces", SourceAnnuaire));

      Retourner 0;

   
   Sinon
   
      Ecran.Ecrire(Message(UpsOrb,"ExportationAnnuaireTermineeEnEchec", SourceAnnuaire));

      Retourner 1;
   
   Fin Si

Sinon

   A=Annuaire(NomDeLAnnuaire);

   Si A.Exporter(SourceAnnuaire, Chemin, Nul) Alors
   
      Ecran.Ecrire(Message(UpsOrb, "ExportationAnnuaireTermineeAvecSucces", SourceAnnuaire));

      Retourner 0;
   
   Sinon
   
      Ecran.Ecrire(Message(UpsOrb, "ExportationAnnuaireTermineeEnEchec", SourceAnnuaire));

      Retourner 1;
   
   Fin Si

Fin Si



Retourner 0;

Fin Fonction



Fonction ExecuterImporterAnnuaire() Retourner Entier

/**************************************************/

Variable

/******/

   A : Nul Ou Annuaire;



Debut

Si NomDeLAnnuaire==Nul Ou SourceAnnuaire==Nul Alors

   Ecran.Ecrire(Message(UpsOrb, "UsageUpsSecImporterAnnuaire"));

   Retourner 1;

Fin Si



Si Detail Alors

   Ecran.Ecrire(Message(UpsOrb,"ImportationDeLAnnuaire", SourceAnnuaire));

   A=Annuaire(NomDeLAnnuaire);

   Si A.Importer(SourceAnnuaire, EnvoyerMessage) Alors
   
      Ecran.Ecrire(Message(UpsOrb,"ImportationAnnuaireTermineeAvecSucces", SourceAnnuaire));

      Retourner 0;
   
   Sinon
   
      Ecran.Ecrire(Message(UpsOrb, "ImportationAnnuaireTermineeEnEchec", SourceAnnuaire));

      Retourner 1;
   
   Fin Si

Sinon

   Si A.Importer(SourceAnnuaire, Nul) Alors
   
      Ecran.Ecrire(Message(UpsOrb, "ImportationAnnuaireTermineeAvecSucces", SourceAnnuaire));

      Retourner 0;
   
   Sinon
   
      Ecran.Ecrire(Message(UpsOrb, "ImportationAnnuaireTermineeEnEchec", SourceAnnuaire));

      Retourner 1;
   
   Fin Si

Fin Si



Retourner 0;

Fin Fonction



Fonction ExecuterSupprimerAnnuaire() Retourner Entier

/***************************************************/

Variable

/******/

   A : Nul Ou Annuaire;



Debut

Si NomDeLAnnuaire==Nul Alors

   Ecran.Ecrire(Message(UpsOrb, "UsageUpsSecSupprimerAnnuaire"));

   Retourner 1;

Fin Si



Si Detail Alors

   Ecran.Ecrire(Message(UpsOrb,"SuppressionDeLAnnuaire", NomDeLAnnuaire));

Fin Si

A=Annuaire(NomDeLAnnuaire);

A.Supprimer();

Ecran.Ecrire(Message(UpsOrb, "SuppressionAnnuaireTerminee", NomDeLAnnuaire));



Retourner 0;

Fin Fonction



Procedure PrincipalServeur()

/**************************/

Variable

/*******/

   I:Entier;

   NomDuServeur : Nul Ou Caractere;

   NomDuParametre : Caractere;

   ModuleUpsFts : Nul Ou Module;

   ModuleUpsCns : Nul Ou Module;

   ModuleUpsMls : Nul Ou Module;

   ModuleUpsDrs : Nul Ou Module;



Debut

Journal.Ecrire(Message(Global,"DemarrageUpsOrb",Caractere(DateSysteme())));

Si EstLeServeurMaitre Alors

   ChargerConfiguration();

Sinon

   DemarrerNoeud();

   LireConfiguration();

Fin Si



I=1;

TantQue Vrai Faire

   NomDuParametre=Traduire(Global,SectionParametre,"Serveur")+Caractere(I,"&&&#");

   Si Non(LireParametre(Global,NomDuParametre,"UpsOrb",NomDuServeur)) Alors
   
      Arreter;
   
   Fin Si

   Selon NomDuServeur Faire
   
      Cas Pour "UpsFts" Faire
      
         ModuleUpsFts=Module(NomDuServeur, 2, 0, 0);
      
      Fin Cas

      

      Cas Pour "UpsCns" Faire
      
         ModuleUpsCns=Module(NomDuServeur, 2, 0, 0);
      
      Fin Cas

      

      Cas Pour "UpsMls" Faire
      
         ModuleUpsMls=Module(NomDuServeur, 2, 0, 0);
      
      Fin Cas

      

      Cas Pour "UpsDrs" Faire
      
         ModuleUpsDrs=Module(NomDuServeur, 2, 0, 0);
      
      Fin Cas

      

      Defaut
      
         DemarrerService(NomDuServeur);
      
      Fin Defaut
   
   Fin Selon

   I++;

Fin TantQue



AttraperException

   TantQue Vrai Faire
   
      Attendre(60.0);
   
   Fin TantQue

TraiterException

   Cas Pour ArretProgramme Faire
   
      Journal.Ecrire(Message(Global,"ArretUpsOrb",Caractere(DateSysteme())));
   
   Fin Cas

   

   Defaut
   
      Journal.Ecrire(Message(Global,"ExceptionRecue",Caractere(DateSysteme())));

      Journal.Ecrire(Exception.MessageErreur);

      Exception.Renvoyer();
   
   Fin Defaut

Fin AttraperException



Si EstLeServeurMaitre Alors

   ArreterServeursUpsOrb();

Sinon

   ArreterNoeud(NomNoeud);

Fin Si

ArreterServeursLocaux();

EnregistrerConfiguration();

Fin Procedure



Principal

/*******/

Debut

Si Entete Alors

   Ecran.Ecrire(Message(UpsOrb, "PresentationUpsOrb1")+"\n");

   Ecran.Ecrire(Message(UpsOrb, "PresentationUpsOrb2", Caractere(DateSysteme(),FiltreDate),Caractere(DateSysteme(),FiltreHeure))+"\n");

Fin Si



Si Action!=Nul Alors

   Selon Action Faire
   
      Cas Pour Traduire(UpsOrb, SectionDivers, "CreerAnnuaire") Faire
      
         Retourner ExecuterCreerAnnuaire();
      
      Fin Cas
      

      Cas Pour Traduire(UpsOrb, SectionDivers, "ExporterAnnuaire") Faire
      
         Retourner ExecuterExporterAnnuaire();
      
      Fin Cas

      

      Cas Pour Traduire(UpsOrb, SectionDivers, "ImporterAnnuaire") Faire
      
         Retourner ExecuterImporterAnnuaire();
      
      Fin Cas

      

      Cas Pour Traduire(UpsOrb, SectionDivers, "SupprimerAnnuaire") Faire
      
         Retourner ExecuterSupprimerAnnuaire();
      
      Fin Cas

      

      Defaut
      
         Ecran.Ecrire(Message(UpsOrb, "UsageUpsOrb"));

         Retourner 1;
      
      Fin Defaut
   
   Fin Selon

Sinon

   PrincipalServeur();

Fin Si

Fin Principal