Up ! Mathematical - Vecteur

Ce programme présente l'usage des vecteurs de réels.

Le fichier source est ${UPS_HOME}/upsvtm/demo/${UPS_LANGUAGE}/vecteur.upl.

Cet exemple utilise les instructions de l'extension d'Up ! 5GL pour Up ! Mathematical.

Pour analyser le fichier source, UpsMat.upi doit être déclaré parmi les modules importés dans le fichier ${UPS_HOME}/ini/${UPS_USER}/upsp5l.ini.

Mode compilé

Commande de compilation


upscmp Source=vecteur.upl

Commande d'exécution


vecteur

Mode interprété


upssng Source=vecteur.upl

Fichier source


Source Composant "Exemple d'emploi du type Vecteur" Version 4.0.0;



Procedure EcrireVecteur(Libelle : Caractere, V : Vecteur[?] De Nul Ou Reel)

/*************************************************************************/

Variable

/******/

   I : Entier;

   Ligne : Nul Ou Caractere;



Debut

Ecran.Ecrire(Libelle);

Ecran.Ecrire("-------------"); 

Ligne="{";

Pour I=0 JusquA V.NbDimensions-1 Faire

   Si I!=0 Alors
   
      Ligne+=", ";
   
   Fin Si

   Ligne+=Caractere(V[I], "-&&&.&&&.&&&.&&#,#&&.&&&");

Fin Pour

Ligne+="}";

Ecran.Ecrire(Ligne);

Fin Procedure



Procedure Appliquer1(R : Nul Ou Reel)

/***********************************/

Debut

Ecran.Ecrire(Caractere(R, "-&&&.&&&.&&&.&&#,#&&"));

Fin Procedure



Procedure Appliquer2(R1 : Nul Ou Reel, R2 : Nul Ou Reel)

/******************************************************/

Debut

Ecran.Ecrire(Caractere(R1, "-&&&.&&&.&&&.&&#,#&&")+"+"+Caractere(R2, "-&&&.&&&.&&&.&&#,#&&"));

Fin Procedure



Fonction Appliquer3(R : Nul Ou Reel) Retourner Nul Ou Reel

/********************************************************/

Debut

Retourner -R;

Fin Fonction



Fonction Appliquer4(R1 : Nul Ou Reel, R2 : Nul Ou Reel) Retourner Nul Ou Reel

/***************************************************************************/

Debut

Retourner -(R1+R2);

Fin Fonction



Procedure EcrireMatrice(Libelle : Caractere, M : Matrice[?,?] De Nul Ou Reel)

/***************************************************************************/

Variable

/******/

   I : Entier;

   J : Entier;

   Ligne : Nul Ou Caractere;



Debut

Ecran.Ecrire(Libelle);

Ecran.Ecrire("-------------");

Pour I=0 JusquA M.NbLignes-1 Faire

   Si I==0 Alors
   
      Ligne="{{";
   
   Sinon
   
      Ligne=" {";
   
   Fin Si

   Pour J=0 JusquA M.NbColonnes-1 Faire
   
      Si J!=0 Alors
      
         Ligne+=", ";
      
      Fin Si
      Ligne+=Caractere(M[I,J], "-&&&.&&&.&&&.&&#,#&&.&&&");
   
   Fin Pour

   Si I==M.NbLignes-1 Alors
   
      Ligne+="}}";
   
   Sinon
   
      Ligne+="}";
   
   Fin Si

   Ecran.Ecrire(Ligne);

Fin Pour

Fin Procedure



Principal

/*******/

Variable

/******/

   A : Vecteur[3] De Nul Ou Reel;

   B : Vecteur[3] De Nul Ou Reel;

   C : Nul Ou Vecteur[?] De Nul Ou Reel;

   X : Nul Ou Reel;

   M : Matrice[3,3] De Nul Ou Reel;

   N : Nul Ou Matrice[?,?] De Nul Ou Reel;



Debut

A[0]=1.0;

A[1]=2.0;

A[2]=3.0;

EcrireVecteur("A", A);

B={4.0, 5.0, 6.0};

EcrireVecteur("B", B);

Ecran.Ecrire(");



C=A+B;

EcrireVecteur("A+B", C);

C=-A;

EcrireVecteur("-A", C);

C=A-B;

EcrireVecteur("A-B", C);

N=A*B;

EcrireMatrice("A*B",N);

X=A.B;

Ecran.Ecrire("A.B="+Caractere(X, "-&&&.&&&.&&&.&&#,#&&.&&&"));
C=A.Cloner();

EcrireVecteur("++C", ++C);

EcrireVecteur("--C", --C);

C=C^4;

EcrireVecteur("C^4", C);

Ecran.Ecrire(");



C=2.0;

EcrireVecteur("C=2.0", C);

C+=3.0;

EcrireVecteur("C+=3.0", C);

C-=3.0;

EcrireVecteur("C-=3.0", C);

C*=3.0;

EcrireVecteur("C*=3.0", C);

C/=3.0;

EcrireVecteur("C/=3.0", C);

C^=4;

EcrireVecteur("C^=4", C);

Ecran.Ecrire(");



C=A.Copier(0, 3);

EcrireVecteur("Copier()", C);

C=0.0;

C.Coller(0, A);

EcrireVecteur("Coller()", C);

C=A.Inserer(1, 10.0);

EcrireVecteur("Inserer()", C);

C=A.Supprimer(1);

EcrireVecteur("Supprimer()", C);

C=A.Copier(0, 3);

C.Permuter(0, 2);

EcrireVecteur("Permuter()", C);

Ecran.Ecrire(");



A.Appliquer(Appliquer1);

A.Appliquer(Appliquer2, B);

C=A.Appliquer(Appliquer3);

EcrireVecteur("Appliquer3()", C);

C=A.Appliquer(Appliquer4, B);

EcrireVecteur("Appliquer4()", C);

Ecran.Ecrire(");



A={1.0, 1.0, 2.0};

X=Reel(Abs(A));

Ecran.Ecrire("Abs(A)="+Caractere(X, "-&&&.&&&.&&&.&&#,#&&.&&&"));

Ecran.Ecrire(");



M={A, B, A};

EcrireMatrice("M=A", M);

M={{1.0, 2.0, 3.0}, {4.0, 5.0, 6.0}, {7.0, 8.0, 9.0}};

C=M*A;

EcrireVecteur("M*A", C);

N=M.InsererColonne(1, A);

EcrireMatrice("InsererColonne()", N);

N=M.InsererLigne(1, A);

EcrireMatrice("InsererLigne()", N);

Ecran.Ecrire(");

Fin Principal

Résultat de l'exécution

A ------------- {1,0, 2,0, 3,0} B ------------- {4,0, 5,0, 6,0} A+B ------------- {5,0, 7,0, 9,0} -A ------------- {-1,0, -2,0, -3,0} A-B ------------- {-3,0, -3,0, -3,0} A*B ------------- {{4,0, 5,0, 6,0} {8,0, 10,0, 12,0} {12,0, 15,0, 18,0}} A.B=32,0 ++C ------------- {2,0, 3,0, 4,0} --C ------------- {1,0, 2,0, 3,0} C^4 ------------- {1,0, 16,0, 81,0} C=2.0 ------------- {2,0, 2,0, 2,0} C+=3.0 ------------- {5,0, 5,0, 5,0} C-=3.0 ------------- {2,0, 2,0, 2,0} C*=3.0 ------------- {6,0, 6,0, 6,0} C/=3.0 ------------- {2,0, 2,0, 2,0} C^=4 ------------- {16,0, 16,0, 16,0} Copier() ------------- {1,0, 2,0, 3,0} Coller() ------------- {1,0, 2,0, 3,0} Inserer() ------------- {1,0, 10,0, 2,0, 3,0} Supprimer() ------------- {1,0, 3,0} Permuter() ------------- {3,0, 2,0, 1,0} 1,0 2,0 3,0 1,0+4,0 2,0+5,0 3,0+6,0 Appliquer3() ------------- {-1,0, -2,0, -3,0} Appliquer4() ------------- {-5,0, -7,0, -9,0} Abs(A)=2,449.489 M=A ------------- {{1,0, 1,0, 2,0} {4,0, 5,0, 6,0} {1,0, 1,0, 2,0}} M*A ------------- {9,0, 21,0, 33,0} InsererColonne() ------------- {{1,0, 1,0, 2,0, 3,0} {4,0, 1,0, 5,0, 6,0} {7,0, 2,0, 8,0, 9,0}} InsererLigne() ------------- {{1,0, 2,0, 3,0} {1,0, 1,0, 2,0} {4,0, 5,0, 6,0} {7,0, 8,0, 9,0}}